JVMにホストされた言語

Clojureはホストされた言語として設計され、JVMの型システム、GC、スレッドなどを共有している。Clojureはすべての関数をJVMのバイトコードにコンパイルする。Clojureは素晴らしいJavaライブラリ消費者であり、Javaを呼び出すためのドットターゲットメンバー記法を提供している。クラス名はフルで、またはインポート後には非修飾名で参照することができる。Clojureは、 reify と proxy を利用したJavaインターフェースとクラスの動的な実装をサポートしている:

Javaクラスを利用するのはこのように簡単だ:

(import '[java.time LocalDate])

(defn add-week ^LocalDate [^LocalDate date]
  (.plusDays date 7))

(defn day->str [^LocalDate date]
  (format "%s %s, %s" (.getMonth date) (.getDayOfMonth date) (.getYear date)))

;; 今日から始まる週ごとの日付の無限シーケンス
(def future-weeks (iterate add-week (LocalDate/now)))

(map day->str (take 4 future-weeks))
;; ("JULY 24, 2017" "JULY 31, 2017" "AUGUST 7, 2017" "AUGUST 14, 2017")

これはもう少し複雑な例になる小さいSwingアプリだ

(import '(javax.swing JFrame JLabel JTextField JButton)
        '(java.awt.event ActionListener)
        '(java.awt GridLayout))
(defn celsius []
  (let [frame (JFrame. "Celsius Converter")
        temp-text (JTextField.)
        celsius-label (JLabel. "Celsius")
        convert-button (JButton. "Convert")
        fahrenheit-label (JLabel. "Fahrenheit")]
    (.addActionListener
     convert-button
     (reify ActionListener
            (actionPerformed
             [_ evt]
             (let [c (Double/parseDouble (.getText temp-text))]
               (.setText fahrenheit-label
                         (str (+ 32 (* 1.8 c)) " Fahrenheit"))))))
    (doto frame
      (.setLayout (GridLayout. 2 2 3 3))
      (.add temp-text)
      (.add celsius-label)
      (.add convert-button)
      (.add fahrenheit-label)
      (.setSize 300 80)
      (.setVisible true))))
(celsius)

celsius

← Concurrent Programming ClojureScript →